อุปกรณ์วัดคุณภาพอากาศ ฝุ่น PM2.5 แบบทำเองก้อได้

สถานการณ์ของฝุ่น PM2.5 ตอนนี้ในกรุงเทพเข้าขั้นวิกฤติ ซึ่งจะเห็นได้ว่าอุปกรณ์ที่เกี่ยวกับกันฝุ่นขายหมดกลิ้ง ทั้งหน้ากาก N95 ทั้งเครื่องกรองอากาศ อันไหนใครว่าดี ขายหมด Out of order อย่างรวดเร็ว เลยมันเป็นบทความพิเศษของวันนี้ครับ คือทางผมอยากได้เครื่องวัด PM2.5  ตอนนี้มีลูกเล็ก เห็นท้องฟ้าใสๆ ไม่แน่ใจว่า ฝุ่นจะเป็นอย่างไง ซึ่งตอนนี้ ก็ สั่งซื้อเครื่องวัดไปแล้วก่อนตรุษจีน แต่ของยังมาไม่ถึง ผมเลยต้องแสดงฝีมือทำเองใช้ชั่วคราวก่อน

ช่วงนี้ แม้แต่มิเตอร์วัดฝุ่น ยังขึ้นราคา เคยเห็นพันกว่า ตอนนี้กระโดดไป สามพันแล้ว แต่ผมโชคดี ที่เคยมีไว้หมดแล้วครับ โดยอุปกรณ์นี้จะใช้ Dust Sensor ของ Plantower รุ่น PMSA003 เป็นแบบ Laser Particle Sensor วัดการกระเจิงความแสงที่ผ่านฝุ่น โดยเซ็นเซอร์ตัวนี้ผมได้มานานแล้ว จาก aliexpress ซื้อตอนนี้คงหาไม่ได้แน่ๆ มีตัวไหนก้อใช้ตัวนั้นล่ะครับ โดยผมให้มันแสดงค่า PM1.0 PM2.5 PM10 และ มันยังเปลี่ยนสีตามเลขดัชนีอีกด้วยครับ เลยทำให้ดูง่าย ขึ้นสีแดงเมื่อไร กลับบ้านเลยดีกว่า

  

ทำความเข้าใจ PM2.5

1. ฝุ่นละออง PM 2.5 (Particle Matter Smaller Than 2.5 Micron) คือ ฝุ่นละอองที่มีขนาดเล็กมาก มองไม่เห็น คือเล็กกว่า 2.5 ไมครอน (ไมโครเมตร) หรือ เล็กกว่า 3% ของเส้นผ่านศูนย์กลางเส้นผมเสียอีก ในเมืองใหญ่นั้น สาเหตุหลักๆ คือ จากการเผาไหม้ของเครื่องยนต์ และจากการก่อสร้าง แต่ ฝุ่นยิ่งเล็กแทนที่มันจะตกลงสู่พื้น มันกลับยิ่งแขวนลอยอยู่ในอากาศนานยิ่งขึ้น
2. ฝุ่น PM 2.5 มีอันตรายต่อสุขภาพอย่างชัดเจน เพราะการที่มันเล็กมาก ทำให้มันสามารถผ่านทางเดินหายใจสู่ปอดและสร้างปัญหากับหลอดเลือดได้ง่ายขึ้นเยอะ (พวกที่มีขนาดใหญ่ มักจะโดนดักเอาไว้ตั้งแต่ด้วยขนจมูก และด้วยเมือกและขนโบกตามช่องทางเดินหายใจ) และจะไปเพิ่มความเสี่ยงต่อการเกิดโรคหัวใจและโรคทางเดินหายใจ เพราะมันสามารถทะลุทะลวงผ่านปอดเข้าสู่เส้นเลือดฝอยที่หล่อเลี้ยงอวัยวะทุกส่วนของร่างกาย รวมทั้งสมองและหัวใจ ทำให้เกิดโรคมะเร็ง โรคหัวใจ โรคทางสมอง ฯลฯ แม้กระทั่งทารกในครรภ์ที่แม่สัมผัสกับอนุภาค PM2.5 ก็จะทำให้เด็กเมื่อโตขึ้นมีโอกาสเสี่ยงต่อโรคต่าง ๆ ดังกล่าว และยังมีผลต่อระดับสติปัญญาของเด็กอีกตลอดชีวิต
3. ฝุ่นละออง PM10 เป็นอนุภาคที่มีขนาดใหญ่กว่า มองเห็นด้วยตาเปล่าได้ ถือเป็นอีกมลพิษ

M5Stack PM2.5 Meter

สำหรับโปรเจคนี้ ผมเอา M5 Stack มาใช้นะครับ คิดว่า งานมันน่าจะเหมาะกับอะไรที่มีจอสี อยู่แล้ว หยิบใช้เลย ส่วน Sensor วัดฝุ่น ยี่ห้อ Plantower เป็นแบบ Laser Particle Sensor

1. M5Stack Basic  จาก Gravitech หรือ inex หรือจะสั่งจาก aliexpress ก้อได้ ฮ่าๆ ถ้ารอได้ ข้อด๊ มันมีจอ มีแบตพร้อม มาพร้อมกับเคสสวยๆ ราคาประหยัด

2. PM2.5 Sensor ผมใช้ Plantower  Model: PMSA003 แต่ในไทย ใช้ PMS7003 ของ Gravitech แทนก็ได้นะครับ สิ่งที่ต่างกัน ขนาด กับ ช่องเข้า กับ ช่องลมออก

ในโอกาศหน้าจะทำในรูปแบบที่ราคาถูกลงมานะครับ หลายคนอาจจะสงสัยว่า Sensor ตัวนี้มันน่าจะเชื่อถือได้ไหม ซึ่งจากข้อมูลเพิ่มเติมจากเอกสารของ การศึกษาเซ็นเซอร์หลักการทางแสงราคาถูกสำหรับงานตรวจวัดฝุ่นละอองในอากาศ พบว่า Sensor ของ Plantower มีความ reliability เชื่อถือได้ คงเส้นคงวา แต่จะเอาให้ถูกแป๊ะเลย ต้องเอาไปสอบเทียบครับ แต่ถึงมันไม่ถูกต้อง 100% เราเอามาใช้ดูแนวโน้มล่ะครับ

วิธีการอ่านค่าจาก Plantower นะครับ

โมดุล Plantower  แค่จ่ายไฟให้โมดุล ค่าที่อ่านได้จะออกมาทาง Uart โดยความยาว Package ยาว 32 Byte ประกอบไปด้วยปริมาณฝุ่น PM1.0 , PM2.5 , PM10

/*
PMS1003, PMS5003, PMS7003:
  32 byte long messages via UART 9600 8N1 (3.3V TTL).
DATA(MSB,LSB): Message header (4 bytes), 2 pairs of bytes (MSB,LSB)
  -1(  1,  2): Begin message       (hex:424D, ASCII 'BM')
   0(  3,  4): Message body length (hex:001C, decimal 28)
DATA(MSB,LSB): Message body (28 bytes), 14 pairs of bytes (MSB,LSB)
   1(  5,  6): PM 1.0 [ug/m3] (TSI standard)
   2(  7,  8): PM 2.5 [ug/m3] (TSI standard)
   3(  9, 10): PM 10. [ug/m3] (TSI standard)
   4( 11, 12): PM 1.0 [ug/m3] (std. atmosphere)
   5( 13, 14): PM 2.5 [ug/m3] (std. atmosphere)
   6( 15, 16): PM 10. [ug/m3] (std. atmosphere)
   7( 17, 18): num. particles with diameter > 0.3 um in 100 cm3 of air
   8( 19, 19): num. particles with diameter > 0.5 um in 100 cm3 of air
   9( 21, 22): num. particles with diameter > 1.0 um in 100 cm3 of air
  10( 23, 24): num. particles with diameter > 2.5 um in 100 cm3 of air
  11( 25, 26): num. particles with diameter > 5.0 um in 100 cm3 of air
  12( 27, 28): num. particles with diameter > 10. um in 100 cm3 of air
  13( 29, 30): Reserved
  14( 31, 32): cksum=byte01+..+byte30
*/

โดยอุปกรณ์นี้ เรียกค่า std. atmosphere เป็น Byte ที่ 11-16 มาใช้นะครับ

Hardware

โมดุลที่ผมได้ว่าจะมาสายต่อดังภาพครับ ให้หัน Connector ไปตามภาพนะครับ แล้วใช้

• สายที่ 1 –  VCC  -> (+5V)
• สายที่ 2 – GND ->  (GND)
• สายที่ 3 – RxD -> GPIO16
• สายที่ 4 – TxD -> GPIO17 (ไม่จำเป็น)

Index AQI

โดยสี ผมจะเอามาจากค่า ดัชนีคุณภาพอากาศ ผมเอามาจาก Air4Thai ซึ่งเขาจะระบุว่า การวัด ดัชนีคุณภาพอากาศ ซึ่งค่าวัดมลพิษทั้งหมด 6 ชนิด วิธีการเทียบดูว่าถ้าใดมีผลทำให้ AQI มากสุด ให้แสดงค่านั้นๆ แปลว่า มิเตอร์นี้ไม่ได้ครอบคลุมทุกมลพิษนะครับ วัดแค่ PM2.5 โดยมลพิษที่เอามาประเมิน มีด้วยกัน 6 ชนิด

• ฝุ่นละอองขนาดไม่เกิน 2.5 ไมครอน (PM_2.5) เป็นฝุ่นที่มีเส้นผ่านศูนย์กลางไม่เกิน 2.5 ไมครอน เกิดจากการเผาไหม้ทั้งจากยานพาหนะ การเผาวัสดุการเกษตร ไฟป่า และกระบวนการอุตสาหกรรม สามารถเข้าไปถึงถุงลมในปอดได้ เป็นผลทําให้เกิดโรคในระบบทางเดินหายใจ และโรคปอดต่างๆ หากได้รับในปริมาณมากหรือเป็นเวลานานจะสะสมในเนื้อเยื่อปอด ทําให้การทํางานของปอดเสื่อมประสิทธิภาพลง ทําให้หลอดลมอักเสบ มีอาการหอบหืด
• ฝุ่นละอองขนาดไม่เกิน 10 ไมครอน (PM₁₀) เป็นฝุ่นที่มีขนาดเส้นผ่านศูนย์กลางไม่เกิน 10 ไมครอน เกิดจากการเผาไหม้เชื้อเพลิง การเผาในที่โล่ง กระบวนการอุตสาหกรรม การบด การโม่ หรือการทําให้เป็นผงจากการก่อสร้าง ส่งผลกระทบต่อสุขภาพเนื่องจากเมื่อหายใจเข้าไปสามารถเข้าไปสะสมในระบบทางเดินหายใจ
• ก๊าซโอโซน (O₃) เป็นก๊าซที่ไม่มีสีหรือมีสีฟ้าอ่อน มีกลิ่นฉุน ละลายน้ำได้เล็กน้อย เกิดขึ้นได้ทั้งในระดับบรรยากาศชั้นที่สูงจากผิวโลก และระดับชั้นบรรยากาศผิวโลกที่ใกล้พื้นดิน ก๊าซโอโซนที่เป็นสารมลพิษทางอากาศคือก๊าซโอโซนในชั้นบรรยากาศผิวโลก เกิดจากปฏิกิริยาระหว่างก๊าซออกไซด์ของไนโตรเจน และสารประกอบอินทรีย์ระเหยง่าย โดยมีแสงแดดเป็นตัวเร่งปฏิกิริยา มีผลกระทบต่อสุขภาพ โดยก่อให้เกิดการระคายเคืองตาและระคายเคืองต่อระบบทางเดินหายใจและเยื่อบุต่างๆ ความสามารถในการทำงานของปอดลดลง เหนื่อยเร็ว โดยเฉพาะในเด็ก คนชรา และคนที่เป็นโรคปอดเรื้อรัง
• ก๊าซคาร์บอนมอนอกไซด์ (CO) เป็นก๊าซที่ไม่มีสี กลิ่น และรส เกิดจากการเผาไหม้ที่ไม่สมบูรณ์ของเชื้อเพลิงที่มีคาร์บอนเป็นองค์ประกอบ ก๊าซนี้สามารถสะสมอยู่ในร่างกายได้โดยจะไปรวมตัวกับฮีโมโกลบินในเม็ดเลือดแดงได้ดีกว่าออกซิเจนประมาณ 200-250 เท่า เมื่อหายใจเข้าไปทำให้ก๊าซชนิดนี้จะไปแย่งจับกับฮีโมโกลบินในเลือด เกิดเป็นคาร์บอกซีฮีโมโกลบิน (CoHb) ทำให้การลำเลียงออกซิเจนไปสู่เซลล์ต่างๆ ของร่างกายลดน้อยลง ส่งผลให้ร่างกายเกิดอาการอ่อนเพลีย และหัวใจทำงานหนักขึ้น
• ก๊าซไนโตรเจนไดออกไซด์ (NO₂) เป็นก๊าซที่ไม่มีสีและกลิ่น ละลายน้ำได้เล็กน้อย มีอยู่ทั่วไปในธรรมชาติ หรือเกิดจากการกระทำของมนุษย์ เช่น การเผาไหม้เชื้อเพลิงต่างๆ อุตสาหกรรมบางชนิด เป็นต้น ก๊าซนี้มีผลต่อระบบการมองเห็นและผู้ที่มีอาการหอบหืดหรือ โรคเกี่ยวกับทางเดินหายใจ
• ก๊าซซัลเฟอร์ไดออกไซด์ (SO₂) เป็นก๊าซที่ไม่มีสี หรืออาจมีสีเหลืองอ่อนๆ มีรสและกลิ่นที่ระดับความเข้มข้นสูง เกิดจากธรรมชาติและการเผาไหม้เชื้อเพลิงที่มีกำมะถัน (ซัลเฟอร์) เป็นส่วนประกอบ สามารถละลายน้ำได้ดี สามารถรวมตัวกับสารมลพิษอื่นแล้วก่อตัวเป็นอนุภาคฝุ่นขนาดเล็กได้ ก๊าซนี้มีผลกระทบโดยตรงต่อสุขภาพ ทำให้เกิดการระคายเคืองต่อเยื่อบุตา ผิวหนัง และระบบทางเดินหายใจ หากได้รับเป็นเวลานาน ๆ จะทำให้เป็นโรคหลอดลมอักเสบเรื้อรังได้้

เพื่อความง่าย ให้เข้าถึงง่าย เขาจึงแบ่งสีหรือระดับความปลอดภัยไว้ ทั้งหมด 5 ระดับนะครับ 5 สีด้วย ดังภาพ

โดย PM2.5 และ PM10 ความเข้มข้นของสารมลพิษ ที่เทียบเท่ากับ ค่าดัชนีคุณภาพอากาศ

AQI	PM2.5 (มคก./ลบ.ม.)	PM10 (มคก./ลบ.ม.)
	เฉลี่ย 24 ชั่วโมงต่อเนื่อง
ดีมาก (0 – 25)	0 – 25	0 – 50
ดี (26 – 50)	26 – 37	51 – 80
ปานกลาง (51 – 100)	38 – 50	81 – 120
เริ่มมีผลกระทบกับสุขภาพ (101 – 200)	51 – 90	121 – 180
มีผลกระทบกับสุขภาพ (มากกว่า 200)	91 ขึ้นไป	181 ขึ้นไป

โดยสุดท้าย ผมเอาค่าที่อ่านได้จาก Dust Sensor มาเทียบกับหาค่า AQI แล้วแสดงผลครับ โดยตอนนี้ทำแค่ AQI ของ PM2.5 ก่อนนะครับ ผมยึดเกณท์ PM2.5 อยู่ไม่เกิน 0-50 ug/m3 ถ้า ยังถือว่าปลอดภัย ซึ่งถ้าสีฟ้า หรือ เขียว ดูเป็นแนวโน้มแล้วกันครับ

Source Code

โปรแกรมของทางผม ไม่ได้ใช้ Lib เพิ่มเติมนะครับ เก็บข้อมูลจาก Uart2 แล้ว เอามาคำนาณ แสดงผลเลย ข้อดี ผมว่าถ้ามี sensor ตัวอื่นที่เป็น serial น่าจะเอาประยุกต์ ใช้งานได้เลยไม่ต้องรอ คนทำ Lib นะครับ

#include <M5Stack.h>
#include <HardwareSerial.h>

//const uint8_t PMS_RX=16, PMS_TX=17;
HardwareSerial pmsSerial(2); // UART2 on GPIO16(RX),GPIO17(TX)

// Stock font and GFXFF reference handle
#define GFXFF 1
#define FF18 &FreeSans12pt7b

#define CF_OL24 &Orbitron_Light_24
#define CF_OL32 &Orbitron_Light_32
#define CF_RT24 &Roboto_Thin_24
#define CF_S24  &Satisfy_24
#define CF_Y32  &Yellowtail_32

int PM25AQI;

void setup() {
  M5.begin();
   
  // our debugging output
  Serial.begin(115200);
  
  // sensor baud rate is 9600
  pmsSerial.begin(9600);
}
 
struct pms7003data {
  uint16_t framelen;
  uint16_t pm10_standard, pm25_standard, pm100_standard;
  uint16_t pm10_env, pm25_env, pm100_env;
  uint16_t particles_03um, particles_05um, particles_10um, particles_25um, particles_50um, particles_100um;
  uint16_t unused;
  uint16_t checksum;
};
 
struct pms7003data data;
    
void loop() {

if (readPMSdata(&pmsSerial)) {
    M5.Lcd.setFreeFont(FF18);                 // Select the font
    M5.Lcd.setTextSize(0.5);
    
    if (data.pm25_env <= 25) {
      M5.Lcd.fillScreen(TFT_BLUE);           
      M5.Lcd.setTextColor(TFT_WHITE, TFT_BLUE);    
      M5.Lcd.drawString("GOOD", 160, 160, GFXFF);// Print the string name of the font
      //Good
      PM25AQI = data.pm25_env;
    } else if  ( (data.pm25_env >= 26) &&  (data.pm25_env <= 37) ) {
      M5.Lcd.fillScreen(TFT_GREEN);
      M5.Lcd.setTextColor(TFT_WHITE, TFT_GREEN);
      M5.Lcd.drawString("Moderate", 160, 160, GFXFF);
      //Moderate
      PM25AQI = map(data.pm25_env,26,37,26,50);
    } else if  ( (data.pm25_env >= 38) &&  (data.pm25_env <= 50) ) {
      M5.Lcd.fillScreen(TFT_GREENYELLOW);
      M5.Lcd.setTextColor(TFT_WHITE, TFT_GREENYELLOW);
      M5.Lcd.drawString("unhealthy", 160, 160, GFXFF);t
      //unhealthy for kid
      PM25AQI = map(data.pm25_env,38,50,51,100);
    } else if  ( (data.pm25_env >= 51) &&  (data.pm25_env <= 90) ) {
       M5.Lcd.fillScreen(TFT_ORANGE);           
      M5.Lcd.setTextColor(TFT_WHITE, TFT_ORANGE);
      M5.Lcd.drawString("very unhealthy", 160, 160, GFXFF);  
      //very unhealthy
      PM25AQI = map(data.pm25_env,51,90,101,200);
    } else if (data.pm25_env >= 91) {
      M5.Lcd.fillScreen(TFT_RED);
      M5.Lcd.setTextColor(TFT_WHITE, TFT_RED);
      //Hazardous
      PM25AQI= 201;
      M5.Lcd.drawString("Hazardous", 160, 160, GFXFF);
    } 
  
  //  M5.Lcd.setTextSize(1);
    M5.Lcd.drawString("PM2.5(AQI)", 0, 20, GFXFF);
    
    M5.Lcd.setTextDatum(ML_DATUM);
    M5.Lcd.drawString("PM1:", 0, 195, GFXFF);/
    M5.Lcd.drawNumber( data.pm10_env, 80, 195);
    M5.Lcd.drawString("PM2.5:", 160, 195, GFXFF);
    M5.Lcd.drawNumber( data.pm25_env, 240, 195);
    M5.Lcd.drawString("PM10:", 0, 220, GFXFF);
    M5.Lcd.drawNumber( data.pm100_env, 80, 220);
    
    //M5.Lcd.setTextPadding(80);
    M5.Lcd.setTextDatum(MC_DATUM);
    M5.Lcd.setFreeFont(CF_OL32);
    M5.Lcd.setTextSize(2);
    if (PM25AQI < 200) {
      M5.Lcd.drawNumber( PM25AQI, 160, 100);    
    } else {      
      M5.Lcd.drawString("Over 200", 160, 100, GFXFF);// Print the string name of the font
    }
    
    // Reset text padding to zero (default)
    M5.Lcd.setTextPadding(0);

    printTest();  //debug
 }

  
}

void printTest() {
  
    // reading data was successful!
    Serial.println();
    Serial.println("---------------------------------------");
    Serial.println("Concentration Units (standard)");
    Serial.print("PM 1.0: "); Serial.print(data.pm10_standard);
    Serial.print("\t\tPM 2.5: "); Serial.print(data.pm25_standard);
    Serial.print("\t\tPM 10: "); Serial.println(data.pm100_standard);
    Serial.println("---------------------------------------");
    Serial.println("Concentration Units (environmental)");
    Serial.print("PM 1.0: "); Serial.print(data.pm10_env);
    Serial.print("\t\tPM 2.5: "); Serial.print(data.pm25_env);
    Serial.print("\t\tPM 10: "); Serial.println(data.pm100_env);
    Serial.println("---------------------------------------");
    Serial.print("Particles > 0.3um / 0.1L air:"); Serial.println(data.particles_03um);
    Serial.print("Particles > 0.5um / 0.1L air:"); Serial.println(data.particles_05um);
    Serial.print("Particles > 1.0um / 0.1L air:"); Serial.println(data.particles_10um);
    Serial.print("Particles > 2.5um / 0.1L air:"); Serial.println(data.particles_25um);
    Serial.print("Particles > 5.0um / 0.1L air:"); Serial.println(data.particles_50um);
    Serial.print("Particles > 10.0 um / 0.1L air:"); Serial.println(data.particles_100um);
    Serial.println("---------------------------------------");
  
}
boolean readPMSdata(Stream *s) {
  if (! s->available()) {
    return false;
  }
  
  // Read a byte at a time until we get to the special '0x42' start-byte
  if (s->peek() != 0x42) {
    s->read();
    return false;
  }
 
  // Now read all 32 bytes
  if (s->available() < 32) {
    return false;
  }
    
  uint8_t buffer[32];    
  uint16_t sum = 0;
  s->readBytes(buffer, 32);
 
  // get checksum ready
  for (uint8_t i=0; i<30; i++) {
    sum += buffer[i];
  }
 
  /* debugging
  for (uint8_t i=2; i<32; i++) {
    Serial.print("0x"); Serial.print(buffer[i], HEX); Serial.print(", ");
  }
  Serial.println();
  */
  
  // The data comes in endian'd, this solves it so it works on all platforms
  uint16_t buffer_u16[15];
  for (uint8_t i=0; i<15; i++) {
    buffer_u16[i] = buffer[2 + i*2 + 1];
    buffer_u16[i] += (buffer[2 + i*2] << 8);
  }
 
  // put it into a nice struct :)
  memcpy((void *)&data, (void *)buffer_u16, 30);
 
  if (sum != data.checksum) {
    Serial.println("Checksum failure");
    return false;
  }
  // success!
  return true;
}

เอาล่ะครับ ตอนนี้ เราก้อได้ อุปกรณ์คุณภาพอากาศ PM2.5 แล้ว ตะลุยวัดฝุ่นกันได้เลยครับ

เพิ่มเติมอีกนิดพฤติกรรมของฝุ่น

อนุภาค PM2.5 มันเบาและลอยอยู่สูง แต่คนที่อยู่ภายในบ้าน ใช่กว่าจะปลอดภัยนะครับ ถ้าสภาพข้างนอกดูมีมืดๆ เหมือนฝนตก รีบปิดประตูทุกบานได้เลยครับ อันนี้ประสบการณ์จากที่ผมเดินวัดฝุ่นมา ฝุ่น PM2.5 มันมองไม่เห็น มันไหลเข้ามากับอากาศปกติได้ มันจะทำให้ระคายทางเดินหายใจได้ ถ้าใครรู้สีก หายใจลำบาก เริ่มไอ รีบหาหน้ากาก หรือ เครื่องฟอกอากาศมาด่วนเลย และ ต่อให้มีแอร์ แต่แอร์ไม่ได้มีกรอง PM2.5 ก้อใช่ว่าจะปลอดภัยนะครับเพราะว่า อนุภาค PM2.5 มันลอยอยู่ในอากาศในห้องล่ะครับ ฉะนั้นถ้ารู้สึกไม่ดี รีบปรับปรุงแก้ไขกันด่วน

1.กรองอากาศภายในรถนะครับ 

เครื่องกรองแอร์ของรถทุกรุ่น จะเป็น HEPA อยู่แล้ว เราไม่จำเป็นต้องซื้อเพิ่ม นอกจาก รถเก่ามาก กับ แอร์ทำงานได้ไม่ดี ถึงจะมี HEPA แต่ต้องมั่นเปลี่ยนบ่อยๆนะครับ อันนี้คือที่ผมว่าภายในรถ ปกติจะเกิน 50-80 ug/m3 แต่เขามาในรถจะเหลือ 20 ug/m3 ได้

ถ้าที่วัดได้ภายในรถยนต์ ที่เห็นไส้กรองดำๆ นั้นล่ะครับ วัดได้ 21 ครับ

2.ห้องนอน

ถ้ายังไม่มีเครื่องกรองแนะนำให้ใช้ filtrete 3M ที่เป็นแผ่นใยไฟฟ้าสถิต มาติดที่ filter เพิ่มนะครับ ลดได้เยอะเหมือนกัน

เอา filter มาห่อ ใส่กลับเข้าไป

ตอนนี้ปิดได้ 1 อาทิตย์แล้ว คาดว่าคงเปลี่ยนบ่อยนะครับ และ ก้อเครื่องฟอก ลดฝุ่นได้เร็วกว่า

อ้างอิง

• ข้อมูลดัชนีคุณภาพอากาศ